Đọc số thành chữ bằng MsSql

Bài này mình giới thiệu hàm đọc số thành chữ bằng cách lập trình trong SQL. Các bài viết cùng chức năng Hàm đọc số bằng chữ bằng C#; Hàm đọc số bằng chữ bằng Javascript

1. Hàm SplitString

Trước tiên bạn cần viết hàm SplitString, Hàm này tương tự như hàm Split như các ngôn ngữ lập trình khác, nhưng kết quả trả về là 1 bảng.

--CREATE BY webmaster@hmweb.com.vn

-- Split function

CREATE FUNCTION [dbo].[SplitString]

(

    @myString varchar(500),

    @deliminator varchar(10)

)

RETURNS

@ReturnTable TABLE

(

    [id] [int] IDENTITY(1,1) NOT NULL,

    [part] [varchar](50) NULL

)

AS

BEGIN

    Declare @iSpaces int

    Declare @part varchar(50)

    --initialize spaces

    Select @iSpaces = charindex(@deliminator,@myString,0)

    While @iSpaces > 0

    BEGIN

        Select @part =

            substring(@myString,0,charindex(@deliminator,@myString,0))

        Insert Into @ReturnTable(part)

        Select @part

          Select @myString =

            substring(@mystring,charindex(@deliminator,@myString,0)+

            len(@deliminator),len(@myString)- charindex(' ',@myString,0))

        Select @iSpaces = charindex(@deliminator,@myString,0)

    END

    If len(@myString) > 0

        Insert Into @ReturnTable

        Select @myString

    RETURN

END

2. Hàm đọc số có 3 chữ số.

Tiếp theo bạn cần viết hàm để đọc số có 3 chữ số. Hàm được viết như sau

CREATE FUNCTION [dbo].[fuDocBaSo]
(
@BaSo int
)
RETURNS NVARCHAR(500)
AS
BEGIN

DECLARE @KetQua nvarchar(500)
SET @KetQua=''
DECLARE @TBSo_Chu TABLE
(So int, ChuSo nvarchar(20))
INSERT INTO @TBSo_Chu
SELECT 0, N' không' UNION
SELECT 1, N' một'UNION
SELECT 2, N' hai' UNION
SELECT 3, N' ba' UNION
SELECT 4, N' bốn' UNION
SELECT 5, N' năm' UNION
SELECT 6, N' sáu' UNION
SELECT 7, N' bảy' UNION
SELECT 8, N' tám' UNION
SELECT 9, N' chín'
DECLARE @Tram int
DECLARE @Chuc int
DECLARE @DonVi int
DECLARE @nStr nvarchar(20)
SET @Tram =cast(@BaSo/100 AS int)
SET @Chuc=cast((@BaSo%100)/10 AS int);
SET @DonVi=@BaSo%10
IF (@Tram=0 AND @Chuc=0 AND @DonVi=0) SET @KetQua=''
IF @Tram<>0
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So = @Tram
SET @KetQua = @nStr + N' trăm '
IF @Chuc=0 AND @DonVi<>0 SET @KetQua=@KetQua+ ' linh '
END
IF @Chuc <>0 AND @Chuc<>1
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@Chuc
SET @KetQua = @KetQua + @nStr + N' mươi '
IF @Chuc=0 AND @DonVi<>0
SET @KetQua=@KetQua+ ' linh '
END
IF @Chuc=1 SET @KetQua=@KetQua+ N' mười '
IF @DonVi=1
BEGIN
IF @Chuc<>0 AND @Chuc<>1
SET @KetQua =@KetQua +N' mốt'
ELSE
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@DonVi
SET @KetQua=@KetQua+@nStr
END
END
ELSE
BEGIN
IF @DonVi=5
BEGIN
IF @Chuc=0
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@DonVi
SET @KetQua=@KetQua+@nStr
END
ELSE
SET @KetQua=@KetQua+N' lăm'
END
ELSE
BEGIN
IF @DonVi<>0
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@DonVi
SET @KetQua=@KetQua+@nStr
END
END
END
RETURN @KetQua
END
3. Hàm đọc số có 3 số có thể hàng trăm hoặc hàng chục bằng 0
CREATE FUNCTION [dbo].[fuDocBaSo_Ben]
(
@BaSo int
)
RETURNS NVARCHAR(500)

AS
BEGIN
DECLARE @KetQua nvarchar(500)
SET @KetQua=''
DECLARE @TBSo_Chu TABLE
(So int, ChuSo nvarchar(20))
INSERT INTO @TBSo_Chu
SELECT 0, N' không' UNION
SELECT 1, N' một'UNION
SELECT 2, N' hai' UNION
SELECT 3, N' ba' UNION
SELECT 4, N' bốn' UNION
SELECT 5, N' năm' UNION
SELECT 6, N' sáu' UNION
SELECT 7, N' bảy' UNION
SELECT 8, N' tám' UNION
SELECT 9, N' chín'
DECLARE @Tram int
DECLARE @Chuc int
DECLARE @DonVi int
DECLARE @nStr nvarchar(20)
SET @Tram =cast(@BaSo/100 AS int)
SET @Chuc=cast((@BaSo%100)/10 AS int);
SET @DonVi=@BaSo%10
IF (@Tram=0 AND @Chuc=0 AND @DonVi=0) SET @KetQua=''
IF @Tram<>0
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So = @Tram
SET @KetQua = @nStr + N' trăm '
IF @Chuc=0 AND @DonVi<>0 SET @KetQua=@KetQua+ ' linh '
END
if @Tram=0
BEGIN
if @Chuc=0
BEGIN
if @DonVi=0
SET @KetQua = @KetQua + N' '
else
SET @KetQua = @KetQua + N' không trăm linh'
END

if @Chuc<>0
SET @KetQua = @KetQua + N' không trăm'
END

IF @Chuc <>0 AND @Chuc<>1
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@Chuc
SET @KetQua = @KetQua + @nStr + N' mươi '
IF @Chuc=0 AND @DonVi<>0
SET @KetQua=@KetQua+ ' linh '
END
IF @Chuc=1 SET @KetQua=@KetQua+ N' mười '

IF @DonVi=1
BEGIN
IF @Chuc<>0 AND @Chuc<>1
SET @KetQua =@KetQua +N' mốt'
ELSE
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@DonVi
SET @KetQua=@KetQua+@nStr
END
END
ELSE
BEGIN
IF @DonVi=5
BEGIN
IF @Chuc=0
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@DonVi
SET @KetQua=@KetQua+@nStr
END
ELSE
SET @KetQua=@KetQua+N' lăm'
END
ELSE
BEGIN
IF @DonVi<>0
BEGIN
SELECT @nStr = ChuSo FROM @TBSo_Chu WHERE So=@DonVi
SET @KetQua=@KetQua+@nStr
END
END
END
RETURN @KetQua
END
 4. Hàm đọc số thành chữ

Tiếp theo chúng ta sẽ sử dụng 3 hàm trên vào việc viết hàm đọc số thành chữ.

CREATE FUNCTION [dbo].[fuDocSoThanhChu](@SoCanDoc bigint)
RETURNS nvarchar(200)
AS
BEGIN
DECLARE @DocThanhChu nvarchar(200)

DECLARE @String nvarchar(50)
IF len(@SoCanDoc)>15
BEGIN
SET @DocThanhChu=N'Số quá lớn, Tôi không biết đọc'
END
ELSE
SET @String =Replace(Convert(VARCHAR,CAST(@SoCanDoc AS MONEY),1 ),'.00','')
BEGIN
DECLARE @Count int
SELECT @Count = COUNT(*) FROM dbo.SplitString(@String,',')
DECLARE @tram nvarchar(10)
DECLARE @Nghin nvarchar(10)
DECLARE @Trieu nvarchar(10)
DECLARE @ty nvarchar(10)
DECLARE @nghinty nvarchar(10)
DECLARE @trieuty nvarchar(10)
IF @Count=1
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@SoCanDoc)
END
IF @Count=2
BEGIN
SELECT @Nghin=part FROM dbo.SplitString(@String,',') WHERE id=1
SELECT @tram=part FROM dbo.SplitString(@String,',') WHERE id=2
SET @DocThanhChu=dbo.fuDocBaSo(@Nghin)+N' nghìn '+ dbo.fuDocBaSo_Ben(@tram)
END
IF @Count=3
BEGIN

SELECT @Trieu=part FROM dbo.SplitString(@String,',') WHERE id=1
SELECT @Nghin=part FROM dbo.SplitString(@String,',') WHERE id=2
SELECT @tram = part FROM dbo.SplitString(@String,',') WHERE id=3

IF Cast(@Nghin as int)>0
BEGIN
IF Cast(@tram as int)>0
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@Trieu) +N' triệu' +
dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'+ dbo.fuDocBaSo_Ben(@tram)
END
ELSE
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@Trieu) +N' triệu' +
dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
END
End
ELSE
BEGIN
if Cast(@tram as int) =0
SET @DocThanhChu=dbo.fuDocBaSo(@Trieu) +N' triệu'
else
SET @DocThanhChu=dbo.fuDocBaSo(@Trieu) +N' triệu' +
dbo.fuDocBaSo_Ben(@tram)
END
END
IF @Count=4
BEGIN
SELECT @ty=part FROM dbo.SplitString(@String,',') WHERE id=1
SELECT @Trieu=part FROM dbo.SplitString(@String,',') WHERE id=2
SELECT @Nghin=part FROM dbo.SplitString(@String,',') WHERE id=3
SELECT @tram = part FROM dbo.SplitString(@String,',') WHERE id=4

if cast(@Trieu as int)>0
BEGIN
IF cast(@Nghin as int)>0
BEGIN
if cast(@tram as int)>0
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Trieu) + N' triệu '
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn '
+ dbo.fuDocBaSo_Ben(@tram)
END
else
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
END
END
ELSE
BEGIN
IF cast(@tram as int)>0
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Trieu) + N' triệu '
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn '
+ dbo.fuDocBaSo_Ben(@tram)
END
ELSE
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Trieu) + N' triệu '
END
END
END
ELSE
BEGIN
if cast(@Nghin as int)>0
BEGIN
if Cast(@tram as int)>0
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn '
+ dbo.fuDocBaSo_Ben(@tram)
END
else
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn '
END
END
else
if cast(@tram as int)>0
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@tram)
END
else
BEGIN
SET @DocThanhChu=dbo.fuDocBaSo(@ty) +N' tỷ'
END
END
END
IF @Count=5
BEGIN

SELECT @nghinty =part FROM dbo.SplitString(@String,',') WHERE id=1
SELECT @ty=part FROM dbo.SplitString(@String,',') WHERE id=2
SELECT @Trieu=part FROM dbo.SplitString(@String,',') WHERE id=3
SELECT @Nghin=part FROM dbo.SplitString(@String,',') WHERE id=4
SELECT @tram = part FROM dbo.SplitString(@String,',') WHERE id=5

if cast(@ty as int)>0
BEGIN
if cast(@Trieu as int)>0
BEGIN
if cast(@Nghin as int)>0
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
END
else
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
END
END
else
BEGIN
if cast(@Nghin as int)>0
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
END
else
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn'
+dbo.fuDocBaSo_Ben(@ty) +N' tỷ'
END
END
END
else
BEGIN


if cast(@Trieu as int)>0
BEGIN
if cast(@Nghin as int)>0
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
END
else
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+dbo.fuDocBaSo_Ben(@Trieu) + N' triệu'
END
END
else
BEGIN
if cast(@Nghin as int)>0
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+ dbo.fuDocBaSo_Ben(@Nghin) + N' nghìn'
END
else
BEGIN
if cast(@tram as int)>0
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
+ dbo.fuDocBaSo_Ben(@tram)
else
SET @DocThanhChu= dbo.fuDocBaSo(@nghinty) +N' nghìn tỷ'
END
END
END
END
END
RETURN @DocThanhChu
END

Lập trình với SQL ::Tính tổng

Bài này mình hướng dẫn bạn lập trình bằng SQL sử dụng vòng lặp. Mô tả bằng việc tính tổng của n số nguyên

Mình đã đọc trên các diễn đàn và có nhiều bạn chưa biết dùng vòng lặp trong SQL. Ở đây mình sử dụng SQL dùng vòng lặp để tính tổng của n số nguyên.
Nếu bạn đã từng học lập trình chắc bạn đã làm bài tập tính tổng của n số bằng ngôn ngữ cơ bản như Pascal, C, ... Giải thuật của bài này thì không có gì để bàn vì nó dễ.
Cách  thực hiện trong SQL như sau:

-- =============================================
-- Author:        webmaster@hmweb.com.vn
-- Description:   <Tínt tổng>
-- =============================================

 CREATE FUNCTION [dbo].[fuTinhTong]
(
      @n int
)
RETURNS bigint
AS
BEGIN
      DECLARE @i int
      SET @i=0
      DECLARE @Tong bigint
      SET @Tong=0
        -- Dùng vòng lặp
      WHILE @i<=@n
      BEGIN
            SET @Tong = @Tong+@i 
            SET @i=@i+1
      END
      RETURN  @Tong
END
Bạn chạy thử hàm trên như sau:
SELECT dbo.fuTinhTong(20) AS Tong20 -->210
SELECT dbo.fuTinhTong(10) AS Tong20 -->55
Áp dụng bài này: Trong bài viết trước mình đã viết hàm Tính số ngày trong tháng; Khi bạn cần tính số liệu thống kê theo tháng bạn có thể thực hiện như mô tả dưới đây
DECLARE @DayOfMonth int
SET @DayOfMonth = dbo.DaysInMonth(@Thang,@nam)
IF @DayOfMonth IS NULL SET @DayOfMonth=0
DECLARE @i int
SET @i=1
WHILE @i<=@DayOfMonth
BEGIN
      -- {Khối lệnh cần tính toán}
      SET @i=@i+1
END

Lập trình với SQL : Phương trình bậc 2

Bài này mình hướng dẫn bạn lập trình bằng SQL; mô tả bằng việc giải phương trình bậc 2 trong SQL. Đây không phải là bài toán khó nhưng cái mình muốn giới thiệu đó là cách dùng ngôn ngữ SQL để lập trình.

Bạn đã quen với phương trình bậc 2  ax2+bx+c=0 với thuật giải:

Nếu a=0
    Không phải bậc 2
Nếu a>0
    Tình delta=b2-4*a*c
    Nếu delta>0
        Phương trình có 2 nghiệm, x1,x2
    Nếu delta=0
        Phương trình có nghiệm kép x=...
    Nếu delta<0
        Phương trình vô nghiệm

Thuật toán thì dễ nhưng có thể có nhiều bạn chưa biết lập trình trong SQL.

-- =============================================
-- Author:        webmaster@hmweb.com.vn
-- Description:   <Giải PT bậc 2>
-- =============================================

CREATE FUNCTION fuPhuongTrinhBac2
(
      @a decimal(18,2),
      @b decimal(18,2),
      @c decimal(18,2)
)
RETURNS nvarchar(2000)
AS
BEGIN
      DECLARE @delta decimal(18,2)
      SET @delta=0.00
      DECLARE @Result nvarchar(2000)
      SET @Result=''
      IF @a=0
            SET @Result=N'Phương trình không phải bậc 2'
      ELSE
      BEGIN
           SET @delta=@b*@b-4*@a*@c
           IF @delta>0
           BEGIN
                SET @Result=@Result+ N'Phương trình có 2 nghiệm:
                x1='+ Cast(((-@b)+SQRT(@delta))/(2*@a) AS nvarchar(300))+';'
                SET @Result=@Result+ N'
                x2='+ Cast(((-@b)-SQRT(@delta))/(2*@a) AS nvarchar(300))+''
           END
           IF @delta=0
           BEGIN
                SET @Result=@Result+ N'Phương trình có nghiệm kép
                x ='+ Cast( ((-@b)/(2*@a)) AS nvarchar(300))+';'
           END
           IF @delta<0
               SET @Result=@Result+ N'Phương trình vô nghiệm'
            END
      RETURN @Result
END
Bạn chạy thử hàm trên với lệnh:
SELECT dbo.fuPhuongTrinhBac2 (1,4,-3) AS PTB2  
--Phương trình có 2 nghiệm: x1=0.645751; x2=-4.64575
SELECT dbo.fuPhuongTrinhBac2 (1,2,-3) AS PTB2  
-- Phương trình có 2 nghiệm: x1=1; x2=-3
SELECT dbo.fuPhuongTrinhBac2 (1,4,0) AS PTB2   
-- Phương trình có 2 nghiệm: x1=0; x2=-4

Sử dụng và quản lý Database Mail

SQL Server 2005 có một hệ thống mail nhỏ được gọi là Database Mail. Database Mail là một tính năng được cải thiện trong SQL Mail so với các phiên bản trước đó của SQL Server. Với tính năng này bạn có thể thiết lập nhiều tài khoản cũng như hồ sơ để hỗ trợ những vấn đề về email. Database Mail là gì?

Database Mail là một hệ thống hàng đợi của mail. Các email message được lưu trong một hàng đợi bên trong cơ sở dữ liệu để được xử lý. Khi một email message được đưa vào trong hàng đợi, một quá trình mở sẽ được kích hoạt để gửi email messages trong hàng đợi đến mail server thích hợp. Khi email đã được gửi thì một email message có trạng thái của phân phối sẽ được gửi trở lại cho SQL Server.

Kích hoạt Database Mail

Database Mail không ở trạng thái có sẵn khi cài đặt. Từ mô hình bảo mật của SQL Server có một số thứ bị tắt mặc định, bạn cần phải kích hoạt Database Mail nếu muốn sử dụng nó. Bạn có thể sử dụng công cụ cấu hình Surface Area Configuration hoặc T-SQL Server dưới đây để kích hoạt Database Mail:

sp_configure 'show advanced options', 1;
GO
RECONFIGURE;
GO
sp_configure 'Database Mail XPs', 1;
GO
RECONFIGURE
GO

 

Thiết lập tài khoản

Một tài khoản Database Mail cho biết SQL Server 2005 phải truyền thông như thế nào với máy chủ SMTP. Tài khoản chỉ rõ email được định dạng và được gửi như thế nào. Một tài khoản sẽ nhận dạng một máy chủ SMTP và phương pháp thẩm định. Tài khoản được sử dụng cho Database Mail không tương ứng với tài khoản đăng nhập của SQL Server.

Khi thiết lập một tài khoản, bạn cần phải chỉ ra đủ thông tin để SQL Server 2005 có thể truyền thông với máy chủ SMTP và thẩm định lại nó nếu cần thiết. Tham khảo các nguồn dữ liệu có online để có danh sách đầy đủ về các tùy chọn trong việc định nghĩa một tài khoản. Bạn có thể thiết lập một tài khoản bằng sử dụng Database Mail Configuration Wizard, chức năng này có thể được tìm thấy ở dưới “Database Mail” trong thư mục “Management” bên trong SQL Server Management Studio, hoặc bằng sử dụng thủ tục được lưu (SP) “sysmail_add_account_sp”. Đây là một đoạn mã sử dụng phương pháp SP ở trên để tạo một tài khoản cho phép truyền thông với một máy chủ SMTP không yêu cầu sự thẩm định:

 

EXECUTE msdb.dbo.sysmail_add_account_sp
@account_name = 'Database Administration Account',
@description = 'Mail account for used by DBA staff',
@email_address = 'ProdServer01@domainname.com',
@display_name = 'ProdServer01 DBA Mail',
@replyto_address = 'Greg.Larsen@domainname.com',
@mailserver_name = 'mailserver.domainname.com';

Tài khoản này có tên là “Database Administration Account”, và có địa chỉ email là ProdServer01@domainname.com. Một trong những ưu điểm của việc sử dụng Database Mail là địa chỉ email này không nhất thiết phải là một tài khoản email hợp lệ trong hệ thống mail. Thêm vào đó, bạn lại có thể kết hợp một địa chỉ “reply to” với một tài khoản mail cơ sở dữ liệu của bạn. trong ví dụ của tôi ở trên, tôi đã định nghĩa Greg.Larsen@domainname.com là @replyto_address. Vì vậy khi một ai đó nhận đươc một email từ bất kỳ các quá trình thông báo email tự động nào của tôi họ sẽ có thể trả lời nó và email có thể được gửi trực tiếp đến tôi.

Với Database Mail, bạn có thể thiết lập nhiều tài khoản email nếu muốn. Trong phần dưới đây tôi sẽ giới thiệu một số lý do tại sao bạn lại có thể thiết lập được nhiều tài khoản Database Mail như vậy.

Thiết lập hồ sơ và liên kết nó với các tài khoản

Trước khi gửi một Database Mail đến máy chủ SMTP đã được phân biệt trong một tài khoản, bạn cần phải kết hợp tài khoản với một hồ sơ (profile) và cho phép truy cập đến profile. Database Mail profile được sử dụng để cải thiện bảo mật mail. Có hai loại profile: public và private. Public profile luôn được áp dụng cho bất cứ ai được phép truy cập đến cơ sở dữ liệu msdb và là một thành viên của DatabaseMailUserRole trong cơ sở dữ liệu msdb. Trong khi đó private profile chỉ có thể được sử dụng cho những người dùng đặc biệt được phép truy cập vào private profile. Một mail profile có thể được kết hợp với một hay nhiều tài khoản khác. Bạn có thể quản lý các profile bằng Database Mail Configuration Wizard, hoặc sử dụng lệnh T-SQL Server giống như thiết lập cho một mail profile dưới đây:

-- Create a Database Mail profile
EXECUTE msdb.dbo.sysmail_add_profile_sp
    @profile_name = 'Database Administration Profile',
    @description = 'Mail Profile for use by DBA processes';

 

Ở đây tôi đã tạo một profile có tên là “Database Administration Profile”. Có một profile đã tạo không có nghĩa là bạn có thể sử dụng profile này để gửi email. Bạn vẫn cần phải kết hợp nó với ít nhật một tài khoản Database Mail và một người dùng bên trong dữ liệu msdb. Để thực hiện điều đó tôi có thể chạy hai lệnh dưới đây:

 

-- Add the account to the profile
EXECUTE msdb.dbo.sysmail_add_profileaccount_sp
    @profile_name = 'Database Administration Profile',
    @account_name = 'Database Administration Account',
    @sequence_number =1 ;
-- Grant access to the profile
EXECUTE msdb.dbo.sysmail_add_principalprofile_sp
    @profile_name = 'Database Administration Profile',
    @principal_name = 'ProdServer01',

Câu lệnh EXECUTE đầu tiên sẽ kết hợp profile của tôi với một tài khoản. Câu lệnh thứ hai sẽ kết hợp profile với cơ sở dữ liệu msdb người dùng ‘ProdServer01’. Những người dùng này cần phải được cho phép là thành viên trong DatabaseMailUserRole trước khi họ có thể gửi mail. Khi tôi kết hợp profile này với một người dùng đặc biệt, thì profile này được hiểu như một private profile. Để tạo một public profile bạn cần phải kết hợp một profile với một “public” database role.

Gửi Database Mail

SQL Server cung cấp SP “sp_send_dbmail” để gửi mail. Cú pháp dưới đây được sử dụng để gọi SP này:

 

 

sp_send_dbmail [ [ @profile_name = ] 'profile_name' ]
    [ , [ @recipients = ] 'recipients [ ; ...n ]' ]
    [ , [ @copy_recipients = ] 'copy_recipient [ ; ...n ]' ]
    [ , [ @blind_copy_recipients = ] 'blind_copy_recipient [ ; ...n ]' ]
    [ , [ @subject = ] 'subject' ]
    [ , [ @body = ] 'body' ]
    [ , [ @body_format = ] 'body_format' ]
    [ , [ @importance = ] 'importance' ]
    [ , [ @sensitivity = ] 'sensitivity' ]
    [ , [ @file_attachments = ] 'attachment [ ; ...n ]' ]
    [ , [ @query = ] 'query' ]
    [ , [ @execute_query_database = ] 'execute_query_database' ]
    [ , [ @attach_query_result_as_file = ] attach_query_result_as_file ]
    [ , [ @query_attachment_filename = ] query_attachment_filename ]
    [ , [ @query_result_header = ] query_result_header ]
    [ , [ @query_result_width = ] query_result_width ]
    [ , [ @query_result_separator = ] 'query_result_separator' ]
    [ , [ @exclude_query_output = ] exclude_query_output ]
    [ , [ @append_query_error = ] append_query_error ]
    [ , [ @query_no_truncate = ] query_no_truncate ]
    [ , [ @mailitem_id = ] mailitem_id ] [ OUTPUT ]

Như những gì bạn nhìn thấy, SP này hỗ trợ một số các tham số khác nhau. Thông tin về mỗi tham số này bạn có thể tham khảo trong các sách online.
Dưới đây là một ví dụ nói về tôi sẽ sử dụng private profile đã được tạo ở trên để gửi một email message đơn giản như thế nào không quan tâm đến quá trình đánh chỉ số lại cơ sở dữ liệu tự động.

 

 

EXEC msdb.dbo.sp_send_dbmail
@profile_name = 'Database Administration Profile',
@recipients = 'greg.larsen@databasejournal.com',
@body = 'Reindex database process completed successfully',
@subject = 'Reindex Database' ;

Database Mail xử lý hết một hàng đợi khi chạy lệnh trên thì tôi sẽ có một thông báo được gửi phản hồi nói rằng mail được đưa vào hàng đợi “Mail queued”. Khi bạn thực thi sp_send_dbmail SP thì mail không được gửi đi ngay lập tức mà thay vì đó nó được lưu trong hàng đợi mail bên trong cơ sở dữ liệu msdb. SP này kích hoạt một quá trình mail mở rộng (DatabaseMail90.exe) để chạy. Thực thi này đọc mail trong hàng đợi và gửi nó đến mail server thích hợp.

Các trường hợp khác nhau trong sử dụng tài khoản và hồ sơ

Có một số cách khác nhau trong việc sử dụng những ưu điểm của đa tài khoản và profile được Database Mail cho phép bạn thực hiện với chúng.

Một trong những ưu điểm quan sát thấy của tính năng đa tài khoản đó là cấu hình profile Database Mail của bạn có thể cho phép khả năng chuyển đổi dự phòng khi một trong những máy chủ SMTP gặp các vấn đề trục trặc. Khi bổ sung vào các tài khoản cho một profile Database Mail bạn có thể cung cấp cho chúng một chuỗi số sequence_number. Khi gửi một email message mới, Database Mail cố gắng gửi nó bằng cách sử dụng số chuỗi thấp nhất trước. Nếu quá trình gửi đó bị hỏng thì Database Mail sẽ sử dụng chuỗi số cao hơn tiếp theo. Database Mail sẽ liên tục thực hiện công việc này cho đến khi mail được gửi thành công hoặc tất cả các tài khoản đã đều được thử.

Một tùy chọn khác trong việc sử dụng này là hỗ trợ cho mail message phân phát đến các địa chỉ email khác nhau. Nếu bạn có nhiều ứng dụng cần phải gửi email, mỗi ứng dụng có một địa chỉ email riêng của nó. Việc làm này sẽ giúp người nhận email tự đông phân biệt được quá trình đã gửi là quá trình gì bằng việc xem địa chỉ email.

Ngoài ra, nếu bạn sử dụng các private profile thì bạn có thể kết hợp các profile này với các chính sách bảo mật khác. Bằng cách đó sẽ cho phép bạn kiểm soát được private profile, người dùng msdb sẽ được phép sử dụng một profile Database Mail riêng biệt.

Kiểm tra Database Mail


SQL Server cung cấp 6 cửa sổ hệ thống khác nhau trong cơ sở dữ liệu msdb cho việc kiểm tra thông tin Database Mail. Các cửa sổ này có thể được sử dụgn để lấy lại thông tin trong cơ sở dữ liệu msdb có cho biết đến cả trạng thái của tất cả Database Mail hoặc chỉ những email message cụ thể. Các cửa sổ này rất hữu dụng trong việc phân biệt mail nào đã được xử lý cũng như lý do tại sao mail message có thể không được phân phối đến mail server yêu cầu. Chúng là các công cụ lý tưởng cho phép bạn có thể kiểm tra và khắc phục một số các vấn đề Database Mail. Để có thêm thông tin chi tiết về các cửa sổ này, bạn có thể tìm hiểu thêm trong các sách online.

sysmail_allitems – cửa sổ này cho phép bạn trả về một tập bản ghi, gồm có một hàng cho mỗi email message được xử lý bằng Database Mail.

sysmail_event_log – Cửa sổ này cho phép bạn trả về một hàng cho mỗi một thông báo lỗi của Windows hoặc SQL Server khi Database Mail xử lý một email message.

sysmail_faileditems – Cửa sổ này trả về một bản ghi cho mỗi một email message có một trạng thái nào đó hoặc bị thất bại.

sysmail_mailattachments – Cửa sổ này gồm một hàng cho mỗi một đính kèm đã gửi

sysmail_sentitems – Cửa sổ này gồm có một bản ghi cho mỗi một email đã được gửi thành công

sysmail_unsentitems – Cửa sổ này gồm có một bản ghi cho mỗi email hiện đang có trong hàng đợi để được gửi hoặc trong quá trình đang gửi.

Duy trì các thông báo trong MSDB Database

Tất cả các email message được lưu trong cơ sở dữ liệu msdb, bạn phải xem xét xem quản lý các thông tin này như thế nào. Phụ thuộc vào các chính sách ghi nhớ email, bạn cần thiết lập một thói quen để làm sạch có chu kỳ đối với các email message không cần thiết nữa. SQL Server 2005 cung cấp hai thủ tục lưu khác nhau để gỡ các bản ghi mail từ cơ sở dữ liệu msdb.

sysmail_delete_mailitems_sp
– SP này xóa thường xuyên các email message có trong msdb trong bảng Database Mail.

sysmail_delete_log_sp – SP này xóa các thông báo bản ghi Database Mail.

Bạn có thể xem sách online để có thêm thông tin chi tiết về SP.

T-SQL Server dưới đây sẽ xóa mail đã được gửi cách đấy một tháng:

DECLARE @delete_date datetime
SET @delete_date = dateadd(MM,-1,getdate())
EXECUTE msdb.dbo.sysmail_delete_mailitems_sp @sent_before=@delete_date

Kết luận

Database Mail SQL Server 2005 là một sự cải thiện lớn trong SQL Mail so với các phiên bản trước đây của SQL Server. Database Mail cung cấp một hệ thống mail với rất nhiều tính năng để bảo vệ và quản lý tốt hơn các mail đang gửi bằng sử dụng T-SQL. Với Database Mail trong SQL Server 2005, bạn không cần phải xây dựng một lời giải cho một giải pháp sử dụng CDOSYS để gửi email. Nếu bạn đang tìm cách để hỗ trợ email từ T-SQL, hãy xem xét đến những tính năng của Database Mail.

 

Các hàm Ranking mới trong SQL Server 2005

Cùng với SQL Server 2005, Microsoft đã giới thiệu một số tính năng mới và những tính năng này sẽ giúp cho chuyên viên về DBA hay SQL Server dễ dàng hơn trong việc viết mã và duy trì cơ sở dữ liệu SQL Server. Bài này sẽ thảo luận về các hàm ranking mới được cung cấp trong SQL Server 2005.


Các tính năng mới đó sẽ giúp bạn dễ dàng viết mã T-SQL để kết hợp xếp loại được tập hợp kết quả của bạn. Bài sẽ hướng dẫn từng phần trong các hàm ranking mới và cung cấp một số ví dụ nhằm minh họa hoạt động của hàm.
Các hàm Ranking là gì?
Các hàm Ranking cho phép bạn có thể đánh số liên tục (xếp loại) cho các tập hợp kết quả. Các hàm này có thể được sử dụng để cung cấp số thứ tự trong hệ thống đánh số tuần tự khác nhau. Có thể hiểu đơn giản như sau: bạn có từng con số nằm trên từng dòng liên tục, tại dòng thứ nhất xếp loại số 1, dòng thứ 2 xếp loại số là 2… Bạn có thể sử dụng hàm ranking theo các nhóm số tuần tự, mỗi một nhóm sẽ được đánh số theo lược đồ 1,2,3 và nhóm tiếp theo lại bắt đầu bằng 1,2,3…
Dữ liệu chạy thử cho các ví dụ
Để có một vài ví dụ cho từng hàm ranking, tôi cần thiết lập một số dữ liệu chạy thử. Trong dữ liệu chạy thử, tôi sử dụng một bảng “Person” khá đơn giản. Bảng sẽ bao gồm 3 cột “FirstName”, “Age” và “Gender”. Đoạn mã dưới nhằm tạo ra và ghi lại dữ liệu chạy thử vào file.

 

SET NOCOUNT ON
CREATE TABLE Person(
FirstName VARCHAR(10),
Age INT,
Gender CHAR(1))
INSERT INTO Person VALUES ('Ted',23,'M')
INSERT INTO Person VALUES ('John',40,'M')
INSERT INTO Person VALUES ('George',6,'M')
INSERT INTO Person VALUES ('Mary',11,'F')
INSERT INTO Person VALUES ('Sam',17,'M')
INSERT INTO Person VALUES ('Doris',6,'F')
INSERT INTO Person VALUES ('Frank',38,'M')
INSERT INTO Person VALUES ('Larry',5,'M')
INSERT INTO Person VALUES ('Sue',29,'F')
INSERT INTO Person VALUES ('Sherry',11,'F')
INSERT INTO Person VALUES ('Marty',23,'F')

Hàm ROW_NUMBER

Hàm đầu tiên tôi muốn nói tới là ROW_NUMBER. Hàm này trả lại một dãy số tuần tự bắt đầu từ 1 cho mỗi dòng hay nhóm trong tập hợp kết quả. Hàm ROW_NUMBER sẽ có cú pháp sau:

ROW_NUMBER ( ) OVER ( [ ] )

Trong đó:

là cột hay tập hợp các cột được sử dụng để quyết định việc gộp nhóm cho hàm ROW_NUMBER áp dụng cho việc đánh số tuần tự.

là một cột hay tập hợp các cột được sử dụng để sắp xếp tập hợp kết quả trong nhóm (partition)

Để hiểu thêm về cách sử dụng hàm ROW_NUMBER, ví dụ dưới sẽ đánh số liên tục cho tất cả các dòng trong bảng Person và sắp xếp chúng theo trường Age

SELECT ROW_NUMBER() OVER (ORDER BY Age) AS [Row Number by Age], 
       FirstName,
       Age 
  FROM Person

Và đây là tập hợp kết quả mã T-SQL trên:

Row Number by Age    FirstName   Age
-------------------- ---------- ------
1                    Larry        5
2                    Doris        6
3                    George       6
4                    Mary         11
5                    Sherry       11
6                    Sam          17
7                    Ted          23
8                    Marty        23
9                    Sue          29
10                   Frank        38
11                   John         40

Bạn có thể thấy tôi đã đánh số liên tục cho toàn bộ các dòng trong bảng Person bắt đầu từ số 1, và tập hợp kết quả được sắp xếp theo cột Age. Sự sắp xếp này được hoàn thiện là do tiêu chuẩn “ORDER BY Age” trong mệnh đề ORDER BY của hàm ROW_NUMBER.

Giả sử bạn không muốn tập hợp kết quả của bạn được sắp xếp mà muốn đưa bảng trở lại sắp xếp theo số bản ghi của từng dòng. Hàm ROW_NUMBER lại luôn yêu cầu phải có mệnh đề ORDER BY, vậy bạn cần phải đưa một giá trị nào đó vào trong mệnh đề này. Trong hàm truy vấn bên dưới tôi đã chỉ định “SELECT 1” vào trong mệnh đề ORDER BY, điều này sẽ chỉ trả lại kết quả là bảng như đã lưu trữ ban đầu và tất nhiên cách đánh số tuần tự vẫn bắt đầu từ 1:

 

SELECT ROW_NUMBER() OVER (ORDER BY (SELECT 1)) AS [Row Number by Record Set],
       FirstName, 
       Age 
  FROM Person

Đây là tập hợp kết quả khi chạy hàm truy vấn trên:

Row Number by Record FirstName   Age
-------------------- ---------- ------
1                    Ted          23
2                    John         40
3                    George       6
4                    Mary         11
5                    Sam          17
6                    Doris        6
7                    Frank        38
8                    Larry        5
9                    Sue          29
10                   Sherry       11
11                   Marty        23

Hàm ROW_NUMBER không chỉ cho phép bạn sắp xếp toàn bộ tập hợp dòng mà còn có thể sử dụng mệnh đề PARTITION để lọc ra nhóm dòng cần đánh số. Các dòng sẽ được đánh số tuần tự trong từng giá trị PARTITION độc nhất. Các dãy số được đánh sẽ luôn bắt đầu từ 1 cho từng giá trị PARTITION mới trong tập hợp bản ghi của bạn. Hãy xem hàm truy vấn dưới đây

 

SELECT ROW_NUMBER() OVER (PARTITION BY Gender ORDER BY Age) AS [Partition by Gender], 
       FirstName, 
       Age,
       Gender 
  FROM Person

Khi chạy truy vấn trên, tập hợp kết quả sẽ ra như sau:

 

Partition by Gender  FirstName  Age         Gender
-------------------- ---------- ----------- ------
1                    Doris      6           F
2                    Mary       11          F
3                    Sherry     11          F
4                    Sue        29          F
1                    Larry      5           M
2                    George     6           M
3                    Sam        17          M
4                    Ted        23          M
5                    Marty      23          M
6                    Frank      38          M
7                    John       40          M

Trong ví dụ này tôi đã phân vùng bởi Gender và sắp xếp theo Age. Thực hành theo ví dụ này sẽ cho phép tôi đánh số tuần tự các bản ghi là Female trong bảng Person theo độ tuổi, và sau đó việc đánh số sẽ bắt đầu lại với nhóm là Male.

Hàm RANK

Đôi khi bạn muốn một dòng có cùng sắp xếp giá trị cột như các dòng khác có cùng một xếp loại. Nếu thế thì hàm RANK () có thể giúp bạn. Hàm RANK có cú pháp như sau:

 

RANK ( ) OVER ( [] )

Trong đó:

 

  • là một cột hay tập hợp các cột được sử dụng để quyết đinh việc đánh số liên tục trong hàm RANK
  • là một cột hay tập hợp các cột được sử dụng để sắp xếp tập hợp kết quả trong nhóm (partition)

Hàm RANK sẽ đánh số liên tục một tập hợp bản ghi nhưng khi có 2 dòng có cùng giá trị sắp xếp thì hàm sẽ đánh giá là cùng bậc giá trị. Giá trị xếp loại vẫn sẽ tăng kể cả khi có 2 dòng cùng giá trị, vì vậy khi đánh giá một giá trị sắp xếp tiếp theo thì số thứ tự vẫn tiếp tục được đánh nhưng sẽ tăng thêm 1 giá trị vào các dòng tiếp theo trong tập hợp.

Đây là ví dụ của hàm rank trong tập hợp bản ghi sắp xếp theo Age:

 

SELECT RANK() OVER (ORDER BY Age) AS [Rank by Age], 
           FirstName, 
           Age
      FROM Person

 

Và kết quả trả về:

Rank by Age          FirstName  Age
-------------------- ---------- ------
1                    Larry      5
2                    Doris      6
2                    George     6
4                    Mary       11
4                    Sherry     11
6                    Sam        17
7                    Ted        23
7                    Marty      23
9                    Sue        29
10                   Frank      38
11                   John       40

Như bạn thấy, với các dòng trùng giá trị Age thì ở phần Rank by Age cũng có cùng giá trị. Bạn có thể thấy Doris và George, Mary và Sherry, cũng tương tự là Ted và Marty, từng cặp một đều có cùng giá trị Rank by Age. Lưu ý rằng Doris và George cùng có xếp loại là 2 nhưng xếp loại của Mary (có giá trị Age tiếp theo) lại không phải 3 mà là 4. Nguyên nhân ở đây là Mary được trả về bản ghi thứ 4 trong tập hợp bản ghi, và hàm RANK() đã lấy số liệu đó khi thiết lập giá trị xếp loại tiếp theo trong Rank by Age

Nếu bạn muốn có một nhiều xếp loại trong tập hợp bản ghi của mình thì với từng xếp loại bạn cần đặt một nhóm cụ thể bằng cách sử dụng mệnh đề PARTITION BY trong hàm RANK. Ví dụ dưới sẽ cho thấy tác dụng khi tôi nhóm xếp loại theo Gender và sắp xếp theo Age

SELECT RANK() OVER (PARTITION BY Gender ORDER BY Age) AS [Partition by Gender],
           FirstName, 
           Age,
           Gender
      FROM Person

Đây là kết quả khi chạy các hàm truy vấn trên:

 

Partition by Gender  FirstName  Age         Gender
-------------------- ---------- ----------- ------
1                    Doris      6           F
2                    Mary       11          F
2                    Sherry     11          F
4                    Sue        29          F
1                    Larry      5           M
2                    George     6           M
3                    Sam        17          M
4                    Ted        23          M
4                    Marty      23          M
6                    Frank      38          M
7                    John       40          M

Bạn có thể thấy là Gioitinh là “F” được bắt đầu xếp loại từ 1 cho đến 4, sau đó bắt đầu đánh số lại từ 1 cho Gioitinh là “M”

Hàm DENSE_RANK

Hàm DENSE_RANK cũng giống như hàm RANK, tuy vậy, hàm này không cung cấp khoảng cách giữa các số xếp loại. Thay vào đó, hàm này sẽ xếp loại liên tục cho từng giá trị ORDER BY cụ thể. Với hàm DENSE_RANK, kể cả khi có hai dòng có cùng giá trị xếp loại thì dòng tiếp theo vẫn chỉ tăng thêm một giá trị so với dòng trên. Hàm DENSE_RANK có cú pháp như hàm RANK.

Đây là hàm DENSE_RANK được tôi sử dụng để xếp loại cho toàn bộ các bản ghi trong bảng Person theo trường Age

 

SELECT DENSE_RANK() OVER (ORDER BY Age) AS [Dense Rank by Age], 
       FirstName, 
       Age
  FROM Person

 

Đoạn mã trên sẽ xuất ra như sau:

Dense Rank by Age    FirstName  Age
-------------------- ---------- -----------
1                    Larry      5
2                    Doris      6
2                    George     6
3                    Mary       11
3                    Sherry     11
4                    Sam        17
5                    Ted        23
5                    Marty      23
6                    Sue        29
7                    Frank      38
8                    John       40

Như bạn thấy các số trong cột “Dense Rank By Age” vẫn đảm bảo tính liên tục, không hề bị ngắt quãng kể cả khi có hai dòng cùng giá trị ORDER BY và giá trị xếp loại như Ted và Marty.

Hàm NTILE

Hàm cuối cùng là hàm NTILE. Đây là hàm được sử dụng để phá vỡ tập hợp bản ghi trong một số cụ thể của các nhóm. Hàm NTILE cũng sử dụng cú pháp như các hàm ranking khác.
Trong ví dụ đầu của hàm này, tôi sẽ nhóm các bản ghi trong bảng Person thành 3 nhóm khác nhau. Tôi muốn các nhóm này dựa trên cột Age. Để làm được điều này, tôi sẽ chạy T-SQL sau:

 

SELECT FirstName, 
       Age, 
       NTILE(3) OVER (ORDER BY Age) AS [Age Groups]
  FROM Person

Đây là tập hợp kết quả của tôi từ câu lệnh T-SQL trên:

 

FirstName  Age         Age Groups
---------- ----------- --------------------
Larry      5           1
Doris      6           1
George     6           1
Mary       11          1
Sherry     11          2
Sam        17          2
Ted        23          2
Marty      23          2
Sue        29          3
Frank      38          3
John       40          3

Trong tập hợp kết quả đã có ở trên với 3 nhóm Age khác nhau. Nhóm đầu tiên bắt đầu từ 5 đến 11 tuổi, nhóm thứ 2 bắt đầu từ 11 đến 23 và nhóm cuối cùng là từ 29 đến 40. Hàm NTILE chỉ có tác dụng chia đều số lượng các bản ghi và đưa vào từng nhóm số. Sử dụng hàm NTILE cho từng bản ghi trong một nhóm sẽ đưa gia các xếp loại giống nhau.

Hàm NTILE là một hàm rất có ích nếu bạn chỉ muốn trả lại một nhóm cụ thể trong các bản ghi. Dưới đây là một ví dụ khi tôi muốn trả lại chỉ nhóm người có độ tuổi chung bình (Nhóm Age 2) từ ví dụ trên.

 

SELECT FirstName,
       Age, 
       Age AS [Age Group]
FROM ( SELECT FirstName, 
              Age, 
              NTILE(3) OVER (ORDER BY Age) AS AgeGroup
        FROM Person) A
WHERE AgeGroup = 2

Kết quả của câu lệnh trên:

FirstName  Age         Age Group
---------- ----------- -----------
Sherry     11          11
Sam        17          17
Ted        23          23
Marty      23          23

 

Kết luận

Mã hóa một quy trình sắp xếp các số tuần tự trong tập hợp bản ghi được sử dụng để lấy một số trong các dòng của mã. SQL Server 2005 đã đưa ra một vài hàm ranking mới. Hy vong trong thời gian tới bạn sẽ cần xếp loại cho các tập hợp bản ghi của mình và một trong các hàm đã được giới thiệu trong bài sẽ giúp bạn hoàn thành công việc đó, nó là một việc hoàn toàn đơn giản.